SCALAR  TX      Ad-valorem tax rate for x sector inputs /0/,
        LENDOW  Labor endowment multiplier              /1/;

$ONTEXT

$MODEL:M1_1S

$SECTORS:
        X       ! Activity level for sector X
        Y       ! Activity level for sector Y
        W       ! Activity level for sector W (Hicksian welfare index)

$COMMODITIES:
        PX      ! Price index for commodity X
        PY      ! Price index for commodity Y
        PL      ! Price index for primary factor L
        PK      ! Price index for primary factor K
        PW      ! Price index for welfare (expenditure function)

$CONSUMERS:
        CONS    ! Income level for consumer CONS

* Taxes are always applied on a value-added basis in an MPSGE modeling.
* Here, the user cost of labor inputs is then PL(1+TX).

$PROD:X s:1
        O:PX    Q:100
        I:PL    Q:40    A:CONS  T:TX
        I:PK    Q:60    A:CONS  T:TX

$PROD:Y s:1
        O:PY    Q:100
        I:PL    Q:60
        I:PK    Q:40

$PROD:W s:1
        O:PW    Q:200
        I:PX    Q:100
        I:PY    Q:100


$DEMAND:CONS
        D:PW    Q:200
        E:PL    Q:(100*LENDOW)
        E:PK    Q:100

$OFFTEXT
$SYSINCLUDE mpsgeset M1_1S

*       An equilibrium in this model determines only relative prices -
*       there is no "money illusion" and the absolute price level is
*       irrelevant.  This must be considered when reporting induced
*       changes in relative prices.  It is convenient to select one
*       good as numeraire and fix its price as unity.  Labor is
*       a traditional choice as numeraire, so we use it:

        PL.FX=1;

*       N.B.  Fixing a price instructs MPSGE to omit the corresponding
*       equation -- In equilibrium, this equation will be satisfied
*       automatically through Walras' law.

*       It is not necessary to fix a numeraire, however if a numeraire
*       is not specified, the normalization of prices is arbitrary.
*       (When no price is exogenously fixed, the system uses one consumer
*       income as normalization, and this income level is determined by the
*       initial price vector).

*        In the folowing statements we declare to check the calibaration.
*        ITERLIM means number of iterations.

* Replicate the benchmark
        M1_1S.ITERLIM = 0;

$INCLUDE M1_1S.GEN
        SOLVE M1_1S USING MCP;
        M1_1S.ITERLIM = 2000;

*       Solve a counterfactual: 50% tax on inputs to X production.
*       LENDOW=1 means labor endowment=100%

        TX = 0.5;
        LENDOW = 1;

$INCLUDE M1_1S.GEN
        SOLVE M1_1S USING MCP;

*       Solve a counterfactual: 100% increase in labor endowment (TX=0)

        TX = 0;
        LENDOW = 2;

$INCLUDE M1_1S.GEN
        SOLVE M1_1S USING MCP;


*       To remove some of the mystery from the model
*       description, we will provide an algebraic presentation of the
*       same equations which have been generated automatically by MPSGE.
*       We write these equations using precisely the same variables
*       which have already been delcared within the MPSGE model
*       (hence, they need not be declared a second time).

*       We need to give names to the equations, however, because the
*       MPSGE-generate equations are not named.


EQUATIONS
        PRF_X   Zero profit for sector X
        PRF_Y   Zero profit for sector Y
        PRF_W   Zero profit for sector w (Hicksian welfare index)

        MKT_X   Supply-demand balance for commodity X
        MKT_Y   Supply-demand balance for commodity Y
        MKT_L   Supply-demand balance for primary factor L
        MKT_K   Supply-demand balance for primary factor K
        MKT_W   Supply-demand balance for aggregate demand

        I_CONS  Income definition for CONS;

* Zero profit conditions: Cost of Production Gross of Tax  =  Value of Output

PRF_X..         100 * PL**0.4 * PK**0.6 * (1+TX) =E= 100 * PX;
PRF_Y..         100 * PL**0.6 * PK**0.4 =E= 100 * PY;
PRF_W..         200 * PX**0.5 * PY**0.5 =E= 200 * PW;

* Market clearance conditions: Output + Initial Endowment = Intermediate + Final Demand

MKT_X..         100 * X =E= 100 * W * PX**0.5 * PY**0.5 / PX;
MKT_Y..         100 * Y =E= 100 * W * PX**0.5 * PY**0.5 / PY;
MKT_W..         200 * W =E= CONS / PW;
MKT_L..         100 * LENDOW =E= 40 * X * PL**0.4 * PK**0.6 / PL +
                                 60 * Y * PL**0.6 * PK**0.4 / PL;
MKT_K..         100 =E= 60 * X * PL**0.4 * PK**0.6 /PK +
                        40 * Y * PL**0.6 * PK**0.4 / PK;

* Income balance: the level of expenditure (CONS) = the value of factor income + tax revenue

I_CONS..        CONS =E= 100*LENDOW*PL + 100*PK + TX*100*X*PL**0.4*PK**0.6;


*       We declare this model using the mixed complementarity syntax
*       in which equation identifiers are associated with variables.


MODEL ALGEBRAIC / PRF_X.X, PRF_Y.Y, PRF_W.W, MKT_X.PX, MKT_Y.PY, MKT_W.PW,
                  MKT_L.PL, MKT_K.PK, I_CONS.CONS /;

* Check the benchmark (again):

        X.L=1; Y.L=1; W.L=1; PX.L=1; PY.L=1; PK.L=1; PW.L=1; CONS.L=200;

        TX=0;
        LENDOW=1;
        SOLVE ALGEBRAIC USING MCP;

*  Solve the same counterfactuals:

        TX=0.5;
        LENDOW=1;
        SOLVE ALGEBRAIC USING MCP;

        TX=0;
        LENDOW=2;
        SOLVE ALGEBRAIC USING MCP;

* Note that if the PL is not fixed, the algebraic model (i.e. version with equations)
* may not solve because the Jacobian is singular at the solution)