SCALAR          LPROD   AGGREGATE LABOR PRODUCTIVITY /1/,
                CX      COST OF X AT BASE YEAR PRODUCTIVITY /1/,
                CY      COST OF Y AT BASE PRODUCTIVITY /1/;

$ONTEXT

$MODEL:LSUPPLY

$SECTORS:
        X       ! SUPPLY=DEMAND FOR X
        Y       ! SUPPLY=DEMAND FOR Y
        LS      ! LABOR SUPPLY

$COMMODITIES:
        PX      ! MARKET PRICE OF GOOD X
        PY      ! MARKET PRICE OF GOOD Y
        PL      ! MARKET WAGE
        PLS     ! CONSUMER VALUE OF LEISURE

$CONSUMERS:
        RA      ! REPRESENTATIVE AGENT

$PROD:LS
        O:PL    Q:LPROD
        I:PLS   Q:1

$PROD:X
        O:PX    Q:1
        I:PL    Q:CX

$PROD:Y
        O:PY    Q:1
        I:PL    Q:CY

$DEMAND:RA      s:1
        E:PLS   Q:120
        D:PLS   Q:1     P:1
        D:PX    Q:1     P:1
        D:PY    Q:1     P:1

$OFFTEXT
$SYSINCLUDE mpsgeset LSUPPLY

$INCLUDE LSUPPLY.GEN
SOLVE LSUPPLY USING MCP;

* We can use this model to evaluate the wage elasticity of labor supply.

* In the initial equilibrium (computed in the last statement) the demands for
* x, y, and L all equal 40. A subsequent assignment to LPROD (below) increases
* labor productivity. After computing a new equilibrium, we can use the change
* in labor supply to determine the wage elasticity of labor supply. The
* elasticity of labor supply should be an input rather than an output of a CGE
* model (this is a parameter for which econometric estimates can be obtained).

* First, we declare some scalar parameters which we will use for reporting,
* then save benchmark labor supply in LS0.

SCALAR
        LSO     REFERENCE LEVEL OF LABOR SUPPLY
        ELS     uncompensated ELASTICITY OF LABOR WRT REAL WAGE;

LSO = LS.L;

* Next we modify the value of scalar LPROD, increasing labor productivity by 1%.
* Because this is a neoclassical model, this change is equivalent to increasing
* the real wage by 1%. We need to recompute equilibrium prices after having
* changed the LPROD value.

LPROD = 1.01;
$INCLUDE LSUPPLY.GEN
SOLVE LSUPPLY USING MCP;

* ELS=(dLS/dw)*(w/LS)=((LS-LS0)/(1.01-1))*(1/LS0)=(LS-LS0)/(LS0*0.01)

ELS = round(100 * (LS.L - LSO) / LSO);

* As the model is currently constructed, the wage elasticity of labor supply
* equals zero. This is beacuse the utility function is Cobb-Douglas over goods
* and leisure, and consumer's only source of income is labor. As the real wage
* rises, this increases both the demand for goods (labor supply) and the demand
* for leisure. These effect exactly balance out and the supply of labor is
* unchanged.

DISPLAY ELS;

*****************************************************************************
*Exercises:
*
*(a) One way in which the labor supply elasticity might differ from zero in a model with
*    Cobb-Douglas final demand is if there were income from some other source.
*    Let the consumer be endowed with good x in addition to labor. What x
*    endowment is consistent with a labor supply elasticity equal to 0.15?
*
* Hint: First, you have to maxU(X,Y,L)=ln(X)+ln(Y)+ln(l) s.t.
*                          Px*X+Py*Y=Pl*(EL-l)+Px*EX
*       where EL - endowment of labor and leisure, l - leisure, EX - endowment of X
*
*       Second, using algebraic deriviation you will find the formula for (El-l)
*
*       Third, use formula for (El-l) to calculate the uncompensated elasticity of
*       labor supply wrt wage.
*       If you done calculations correctlly, you will get the following formula
*       for elasticity (ETA):  ETA=(SHL*PX*EX)/(PL*EL*(1-SHL)-SHL*PX*EX)
*
*       Fourth, calculate EX from the ETA formula
*
*
*(b) A second way to calibrate the labor supply elasticity is to change the
*    utility function. We can do this by changing the "s:1" to "s:SIGMA"
*    (SIGMA is a scalar value representing the benchmark elasticity of
*    substitution between x, y, and L in final demand. Modify the program to
*    include SIGMA as a scalar, and find the value of SIGMA consistent with a
*    labor supply elasticity equal to 0.15
*
*    Hint: Replace Cobb-Douglas utility function by CES function and follow the
*          hint for the previous exercise. The new formula for elasticity will be:
*          ETA=(LEIS/LSUP)*(SIGMA-1)*(1-SHL)
*