*This model begins with GAMS statements in which three scalar parameters are
*declared - we declared x, y and MRS as scalar parameters and initialize the
*first two of these to unity (the MRS parameter is assigned a value following
*the solution of the model).

SCALAR
        X       QUANTITY OF X FOR WHICH THE MRS IS TO BE EVALUATED /1/
        Y       QUANTITY OF Y FOR WHICH THE MRS IS TO BE EVALUATED /1/
        MRS     COMPUTED MARGINAL RATE OF SUBSTITUTION;

*The rest of the model is simpler than first example.

$ONTEXT

$MODEL:MRSCAL

$COMMODITIES:
        PX      ! PRICE INDEX FOR GOOD X
        PY      ! PRICE INDEX FOR GOOD Y

$CONSUMERS:
        RA      ! REPRESENTATIVE AGENT INCOME

$DEMAND:RA      s:1
        D:PX    Q:1     P:(1/4)
        D:PY    Q:1     P:1
        E:PX    Q:X
        E:PY    Q:Y

$OFFTEXT
$SYSINCLUDE mpsgeset MRSCAL

$INCLUDE MRSCAL.GEN
SOLVE MRSCAL USING MCP;

* Following the solution, we compute a function of the solution values
*(the ratio of the PX to the PY and storing this result in the scalar MRS).
MRS = PX.L / PY.L;
OPTION MRS:8;
DISPLAY MRS;

**************************************************************************
*Exercises:
*
*(a) Show that the demand function is homothetic by uniform scaling of the
*    x and y endowments. The resulting MRS should remain unchanged.
*
*(b) Modify the demand function calibration point so that the reference prices
*    of both x and y equal unity.