*       Request the old version of PATH
option mcp=pathold;


*The world endowments for good X and Y are both equal to one.

SCALAR  XA              AGENT A ENDOWMENT OF X ( 0 < XA < 1 )   /0.2/
        YA              AGENT A ENDOWMENT OF Y ( 0 < YA < 1 )   /0.8/
        THETA_A         AGENT A DEMAND SHARE PERAMETER FOR X    /0.5/
        THETA_B         AGENT B DEMAND SHARE PARAMETER FOR X    /0.8/
        SIGMA_A         AGENT A ELASTICITY PARAMETER            /2.0/
        SIGMA_B         AGENT B ELASTICITY PARAMETER            /0.5/;

$ONTEXT

$MODEL:EXCHANGE

$COMMODITIES:
        PX      ! EXCHANGE PRICE OF GOOD X
        PY      ! EXCHANGE PRICE OF GOOD Y

$CONSUMERS:
        A       ! CONSUMER A
        B       ! CONSUMER B

* This model specification uses the default value for reference prices in the
* demand function blocks. When "P:value" is not specified, "P:1" is assumed.

$DEMAND:A       s:SIGMA_A
        E:PX    Q:XA
        E:PY    Q:YA
        D:PX    Q:THETA_A
        D:PY    Q:(1-THETA_A)
* Any numeric input field in an MPSGE model may be "computed"
*(algebraic expression may be enclosed within parantheses and legitimate GAMS code)

$DEMAND:B       s:SIGMA_B
        E:PX    Q:(1-XA)
        E:PY    Q:(1-YA)
        D:PX    Q:THETA_B
        D:PY    Q:(1-THETA_B)

* The $REPORT section of the input file requests the solution system to return
* values for inputs, outputs, final demands or welfare indices at the equilibrium.
* Only those items which are requested will be written to the solution file.
* Each record in the report block begins with a V: (variable name) field.

$REPORT:
         V:XAD   D:PX    DEMAND:A
         V:YAD   D:PY    DEMAND:A
         V:XBD   D:PX    DEMAND:B
         V:YBD   D:PY    DEMAND:B

$OFFTEXT
$SYSINCLUDE mpsgeset EXCHANGE

$INCLUDE EXCHANGE.GEN
SOLVE EXCHANGE USING MCP;

* Absolute levels of income and price are not appropriate for general equilibrium
* modeling. A CGE model determines only relative prices.

SCALAR
        PRATIO                 EQUILIBRIUM PRICE X IN TERMS OF Y
        IRATIO                 EQUILIBRIUM RATIO OF CONSUMER A INCOME TO CONSUMER B INCOME;

PRATIO = PX.L / PY.L;
IRATIO = A.L / B.L;

DISPLAY IRATIO, PRATIO;

* We have to compute an alternative efficient equilibrium where income levels
* for A and B are equal, to demonstrate that when incomes are both fixed,
* the equilibrium remains efficient but the connection between market prices
* and endowment income is eliminated.

A.FX = 1;
B.FX = 1;

$INCLUDE EXCHANGE.GEN
SOLVE EXCHANGE USING MCP;

SCALAR
        TRANSFER        IMPLIED TRANSFER FROM A TO B AS A PERCENTAGE OF INCOME;

TRANSFER=100*(A.L- (PX.L*XA +PY.L*YA));
PRATIO = PX.L/PY.L;
IRATIO = A.L/B.L;

DISPLAY TRANSFER, PRATIO, IRATIO;

******************************************************************************
* Exercises:
*
*(a) Set up two separate models to compute the autarchy price ratios (PRATO) for
*    consumers A (first model) and B (second model)
*
*(b) Determine parameter values in the original model where the endowment point
*    is the equilibrium point
*    (hint: change preferences of A to be the same as his endowment)
*
*(c) Set up a series of computations using original model from which you can
*    sketch the efficiency locus.
*    Draw the Edgeworth box diagram which is consistent with these values.