*       EXERCISE (a).  Derive an analytic expression for the elasticity
*       of labor supply as a function of ESUBL and the benchmark value
*       shares.  Determine values of ESUBL consistent  with labor supply
*       elasticities equal to -0.10, 0, 0.10 and 0.20.


SCALAR  TX      Ad-valorem tax rate for X sector inputs /0/,
        ESUBL Elasticity of substitution for leisure vs. consumption /0.5/,
        LS0         Reference labor supply /100/;

$ONTEXT

$MODEL:M1_4AS

$SECTORS:
        X       ! Activity level for sector X
        Y       ! Activity level for sector Y
        T       ! Labor supply

$COMMODITIES:
        PX      ! Price index for commodity X
        PY      ! Price index for commodity Y
        PL      ! Price index for leisure
        PLS     ! Price index for labor supply (factor L input)
        PK      ! Price index for primary factor K

$CONSUMERS:
        CONS    ! Income level for consumer CONS

$PROD:X s:1
        O:PX  Q:100
        I:PLS Q:40 A:CONS T:TX
        I:PK  Q:60 A:CONS T:TX

$PROD:Y s:1
        O:PY  Q:100
        I:PLS Q:60
        I:PK  Q:40

$PROD:T
        O:PLS
        I:PL

$DEMAND:CONS   s:ESUBL  con:1
        D:PX   Q:100    con:
        D:PY   Q:100    con:
        D:PL   Q:100
        E:PL   Q:200
        E:PK   Q:100

*       Recover a Hicksian welfare index (to be used in exercise b):
$REPORT:
        V:WELF  W:CONS

$OFFTEXT

$SYSINCLUDE mpsgeset M1_4AS

*       Replicate the benchmark (initialize value of labor supply):

        T.L = LS0;
        TX = 0;
        M1_4AS.ITERLIM = 0;

$INCLUDE M1_4AS.GEN
        SOLVE M1_4AS USING MCP;

*-------------------------------------------------------------------------
*       Analytical expression of labor supply elasticity:

$ontext
        The algebraic derivation of the uncompensated labor supply
        elasticity from a nested CES utility function (like the specified
        in the block $DEMAND:CONS), gives the following formulae:

        ETA = (LEIS/LSUP) * {ESUBL - (ESUBL - 1)*Shl - LEND*PL/M}

        Where:
                ETA  = Uncompensated labor supply elasticity
                LEIS = Demand for leisure
                LS0  = Supply of labor
                ESUBL= Compensated labor supply elasticity
                Shl  = Value share of leisure in consumption
                LEND = Labor endowment
                PL   = Price of labor
                M    = Total income of consumer

        Solving for ESUBL:

        ESUBL = {(LSUP/LEIS)*ETA + LEND*PL/M - Shl} / (1 - Shl)

                Compute induced changes in labor supply using the labor
                market marginal', PL.M.  This marginal returns the net
                excess supply of labor at the given prices.  We started
                from a balanced benchmark, with no change in labor demand
                (with iteration limit equal to zero).  Hence, PL.M returns
                the magnitude of the change in labor supply.  We multiply by
                the benchmark wage (1) and divide by the benchmark labor
                supply (LS0) to produce a finite difference approximation
                of the elasticity.

        The ELS can be written as:
                ELS = PL.M / (PL.L - 1) * (1 / LS0)
$offtext

*       Introduce a change in the price of labor:

        PL.L = 1.001;

*        Compute the compensated labor supply elasticity.  At
*        benchmark PL = 1, LEIS = 100, LEND = 200, M = 300.  Hence we
*        can write the compensated labor supply elasticity as:
*                ESUBL = (ETA + (2/3) - (1/3)) / (2/3)


SET             SC         Scenarios /SC1* SC4/;

PARAMETER       ESVAL(SC)  Values of ESUBL by scenario
                ETA(SC)    Uncompensated labor supply elasticity by scenario
                           /SC1 -0.10, SC2 0, SC3 0.10, SC4 0.20/
                ELS(SC)    Calibrated labor supply elasticity;

LOOP(SC,
*       Install a tax rate for the current scenario:

                ESVAL(SC) = (ETA(SC) + (2/3) - (1/3)) / (2/3);
                ESUBL = ESVAL(SC);

$INCLUDE M1_4AS.GEN
        SOLVE M1_4AS USING MCP;

*       Check the labor supply elasticity:

        ELS(SC) = PL.M / (PL.L - 1) * (1/LS0);
);

OPTION DECIMALS = 2;
DISPLAY ESVAL, ELS;


        M1_4AS.ITERLIM = 2000;
*------------------------------------------------------------------------
*       EXERCISE (b):  Plot excess burden versus the price elasticity
*       of labor supply over the range -0.10 to 0.20.

*        Note that in a model where tax revenues are accrued to the
*        consumer, the excess burden of taxation is the change in the
*        Hicksian welfare index

*       Tax on sector X inputs:

        TX = 1;

*       Compute excess burden:

        PARAMETER     EX_BURDEN(SC)   % excess burden by scenario;

LOOP(SC,

*       Install a ESUBL for the current scenario:

                ESVAL(SC) = ETA(SC)*(3/2) + (1/2);
                ESUBL = ESVAL(SC);

$INCLUDE M1_4AS.GEN
        SOLVE M1_4AS USING MCP;

*       Compute excess burden (the negative of welfare index change):

        EX_BURDEN(SC) = (WELF.L - 1) * 100;
);

DISPLAY ESVAL, ETA, EX_BURDEN;