SCALAR  XA              AGENT A ENDOWMENT OF X (0 < XA < 1)     /0.2/
        YA              AGENT A ENDOWMENT OF Y (0 < YA < 1)     /0.8/
        THETA_A         AGENT A DEMAND SHARE PARAMETER FOR X    /0.5/
        THETA_B         AGENT B DEMAND SHARE PARAMETER FOR X    /0.8/
        SIGMA_A         AGENT A ELASTICITY PARAMETER            /2.0/
        SIGMA_B         AGENT B ELASTICITY PARAMETER            /0.5/;


*-------MODEL: CONSUMER A AUTARCHY

$ONTEXT

$MODEL:AUTAR_A

$COMMODITIES:
        PX      ! AUTAR_A PRICE OF GOOD X
        PY      ! AUTAR_A PRICE OF GOOD Y

$CONSUMERS:
        A       ! CONSUMER A

$DEMAND:A       s:SIGMA_A
        E:PX    Q:XA
        E:PY    Q:YA
        D:PX    Q:THETA_A
        D:PY    Q:(1-THETA_A)

$OFFTEXT
$SYSINCLUDE mpsgeset AUTAR_A

$INCLUDE AUTAR_A.GEN
SOLVE AUTAR_A USING MCP;

*       Compute the price ratio:
PARAMETER       PRICER          PRICE RATIO OF THE AUTARCHY MODELS;
PRICER("AUT_A","PRATIO") = PX.L / PY.L;


*-------MODEL: CONSUMER B AUTARCHY

$ONTEXT

$MODEL:AUTAR_B

$COMMODITIES:
        PX      ! AUTAR_B PRICE OF GOOD X
        PY      ! AUTAR_B PRICE OF GOOD Y

$CONSUMERS:
        B       ! CONSUMER B

$DEMAND:B       s:SIGMA_B
        E:PX    Q:(1-XA)
        E:PY    Q:(1-YA)
        D:PX    Q:THETA_B
        D:PY    Q:(1-THETA_B)

$OFFTEXT
$SYSINCLUDE mpsgeset AUTAR_B

$INCLUDE AUTAR_B.GEN
SOLVE AUTAR_B USING MCP;

*       Compute the price ratio:
PRICER("AUT_B","PRATIO") = PX.L / PY.L;

DISPLAY PRICER;